Antworten auf deine Fragen:
Neues Thema erstellen

Antworten zum Thema „Swipe Gesture“

D

DaFunsel

Guest

Hallo zusammen.
Ich bin mal wieder dabei ein wenig zu spielen.
Mein Ziel ist es, eine einfache Swipe Funktion zu schreiben. Im Netz habe ich ein Tutorial gefunden. Dort wird ein MC erstellt ("square_mc"), zudem folgendes Script:
Code:
import flash.ui.Multitouch;
import flash.ui.MultitouchInputMode;
Multitouch.inputMode = MultitouchInputMode.GESTURE;

square_mc.addEventListener(TransformGestureEvent.GESTURE_SWIPE , onSwipe);
function onSwipe (e:TransformGestureEvent):void{
if (e.offsetX == 1) {
//User swiped towards right
square_mc.x += 320;
}
if (e.offsetX == -1) {
//User swiped towards left
square_mc.x -= 320;
}
}
Das funktioniert auf dem iPhone ganz gut. Das ist eine sehr einfache Anweisung. Dort wird nicht gesagt das es ein "smoother" Übergang zum nächsten Bild sein soll und das Ende nach links/rechts ist auch nicht definiert.

Ich habe noch ein anderes Tutorial gefunden, das funktioniert bei mir nicht richtig gut und ist für meine Verhältnisse nicht ausreichend erklärt und nachvollziehbar (kann es sein, das es nicht richtig funktioniert, weil er das in CS5.5 und ich in CS5 geschrieben hat?):
Code:
package  {
    
    import flash.display.MovieClip;
    import flash.ui.Multitouch;
    import flash.ui.MultitouchInputMode;
    import flash.events.TransformGestureEvent;
    import flash.events.Event;
    
    
    public class Swipe extends MovieClip {
        
        private var currentTile:Number = 1;
        private var totalTiles:Number = 4;
        private var slideCounter:Number = 0;
        
        
        public function Swipe() {
            
            if(Multitouch.supportsGestureEvents)
            {
                init();
            }else{
                trace("No Gestures");
            }
             
        }
        private function init():void
        {
            Multitouch.inputMode = MultitouchInputMode.GESTURE;
            this.stage.addEventListener(TransformGestureEvent.GESTURE_SWIPE, handleSwipe);
        }
        
        private function handleSwipe(event:TransformGestureEvent):void
        {
            if(event.offsetX == 1)
            {
                if(currentTile > 1)
                {
                    slideRight();
                    currentTile--;
                }
            } else if(event.offsetX == -1)
            {
                if(currentTile < totalTiles)
                {
                    slideLeft();
                    currentTile++;
                }
            }
        }
        
        private function slideLeft():void
        {
            tiles.addEventListener("enterFrame", moveTilesLeft);
        }
        private function slideRight():void
        {
            tiles.addEventListener("enterFrame", moveTilesRight);
        }
        
        private function moveTilesLeft(event:Event):void
        {
            tiles.x -= 33;
            slideCounter++;
            
            if(slideCounter == 10)
               {
                   tiles.removeEventListener("enterFrame", moveTilesLeft);
                   slideCounter = 0;
               }
            
        }
        
        private function moveTilesRight(event:Event):void
        {
            tiles.x += 33;
            slideCounter++;
            
            if(slideCounter == 10)
               {
                   tiles.removeEventListener("enterFrame", moveTilesRight);
                   slideCounter = 0;
               }
        }
    }
    
}
Dort ist der Übergang so wie ich ihn haben möchte (das Sliden).
Zudem ist dort Anfang und Ende definiert. Beim Testen hängt er sich manchmal auf und ich kann weder vor noch zurück. Das mit den " tiles.x -= 33;" verstehe ich auch nicht ganz. Es wird gesagt, das dies der Freiraum von Bild zur Bühne im MC ist. Ich habe mein Bild der Größe angepasst und die selben Werte genommen. Beim hin und her Sliden werden die Bilder nicht mittig dargestellt, eher alles verschoben (nur das erste Bild stimmt).
Wie macht man das denn, wenn man die Bilder als Vollbild haben möchte? Muss dann "tiles.x -= 0;"?

Was für mich und auch evtl. für andere interessant sein könnte, kann man diese Anweisungen vereinfacht zusammenfassen?
Ich bin wie schon oft geschrieben nicht wirklich fit in AS3. Eine Erklärung ist somit für mich sehr wichtig.

Ich würde mich über eine Antwort sehr freuen.

-->LG<--
 
Zuletzt bearbeitet von einem Moderator:

A

ad86

Guest

AW: Swipe Gesture

Hi,

vorweg, ich hab kein CS5 oder CS5.5 und auch kein iPhone zum Testen.

Wann tritt das swipe-Ereignis auf? Während des swipes mehrmals oder nur einmal, wenn dieses erkannt wurde?

Code:
import flash.ui.Multitouch;
import flash.ui.MultitouchInputMode;
Multitouch.inputMode = MultitouchInputMode.GESTURE;

var moveVal:Number=50;//Betrag pro Frame
var imgCount:int=4;//Anzahl der Bilder
var imgSize:int=320;//Groesse eines Bildes
var gotoX:int=0;//Wohn bei einem Swipe gegangen werden soll
var currentIndex:int=0;//Welches Bild angezeigt wird
var gotoRight:Boolean=false;//OB swipe nach rechts oder nicht
var gotoLeft:Boolean=false;//OB swipe nach links oder nicht


myObject_mc.addEventListener(TransformGestureEvent.GESTURE_SWIPE , onSwipe);

[COLOR="red"]function checkParent(mcName:String, parent_mc:DisplayObject):MovieClip{
   while (parent_mc.name!=mcName && parent_mc!=this.stage){
      parent_mc=parent_mc.parent;
   }
   if (parent_mc==this.stage){
      return null;
   }
   return parent_mc;
}[/COLOR]

function onSwipe (e:TransformGestureEvent):void{
   [COLOR="Red"]var mc:MovieClip=checkParent("myObject_mc", e.target);
   if (mc==null){
      return;
   }[/COLOR]
   if (e.offsetX == 1) {
      if (currentIndex>0){
         currentIndex--;
         [COLOR="red"]animateToRight(mc);[/COLOR]
      }
   }
   if (e.offsetX == -1) {
      if (currentIndex<imgCount-1){
         currentIndex++;
         [COLOR="red"]animateToLeft(mc);[/COLOR]
      }
   }
}

function animateToRight(obj:DisplayObject):void{
   gotoRight=true;
   gotoLeft=false;
   obj.addEventListener(Event.ENTER_FRAME, moveObjHandler);
}

function animateToLeft(obj:DisplayObject):void{
   gotoLeft=true;
   gotoRight=false;
   obj.addEventListener(Event.ENTER_FRAME, moveObjHandler);
}

function moveObjHandler(e:Event):void{
   if (gotoLeft && !gotoRight){
      if (e.target.x> -currentIndex*imgSize+moveVal){ //Wenn x-Position noch größer als aktueller Index*imgSize + moveVal, dann kann x-Position nochmal nach links
         e.target.x-=moveVal;
      }
      else{
         e.target.x= -currentIndex*imgSize;
         gotoLeft=false;//Sonst darf die xPosition nicht weiter nach links gehen
      }
   }
   if (gotoRight && !gotoLeft){
      if (e.target.x< -currentIndex*imgSize-moveVal){//Wenn x-Position noch kleiner als aktueller Index*imgSize + moveVal, dann kann x-Position nochmal nach rechts
         e.target.x+=moveVal;//Sonst darf die xPosition nicht weiter nach rechts gehen
      }
      else{
         e.target.x=-currentIndex*imgSize;
         gotoRight=false;
      }
   }
   if (!gotoRight && !gotoLeft){//Wenn die XPosition weder nach links noch nach rechts, dann entferne EventListener
      e.target.removeEventListener(Event.ENTER_FRAME,moveObjHandler);
   }
}

Das sollte eigentlich funktionieren. Zur Idee: Wenn swipe nach links, soll myObject solange nach links verschoben werden bis die x-Position kleiner als minX ist. Um die Animation zu starten gibt es zwei Möglichkeiten: 1. Über Tweens oder über einen Event.ENTER_FRAME-Handler(wie hier).

Und beim zweiten Tutorial: keine Ahnung was currentTile und totalTiles sein soll. Aber egal, das obere Script sollte ja funktionieren, auch wenn nicht getestet.

tiles.x -= 33; bedeutet (da es im ENTER_FRAME-Handler ist), das pro FRame die xPosition um 33 Einheiten nach links verschoben wird. Man kann es auch länger schreiben:
tiles.x = tiles.x - 33; //also der aktuelle x-wert minus 33;

MFG ad86
 
Zuletzt bearbeitet von einem Moderator:
D

DaFunsel

Guest

AW: Swipe Gesture

Hi.
Danke für die Antwort.
Also für mein Test möchte ich das Swipe-Ereignis dann haben, wenn ich mit meinen Fingern über den Touch streiche.
Zu deinem Script:

-Szene 1, Ebene 'AS', Bild 1, Zeile 18 1118: Implizite Umwandlung von einem Wert mit statischem Typ Object in einen möglicherweise nicht verwandten Typ flash.display:DisplayObject.

-Szene 1, Ebene 'AS', Bild 1, Zeile 22 1118: Implizite Umwandlung von einem Wert mit statischem Typ Object in einen möglicherweise nicht verwandten Typ flash.display:DisplayObject.

-->LG<--
 
A

ad86

Guest

AW: Swipe Gesture

Hi,
Also für mein Test möchte ich das Swipe-Ereignis dann haben, wenn ich mit meinen Fingern über den Touch streiche.
Das war eher die Frage, wie Flash es händelt. Auf dem iPhone (mit ObjC) ist das glaub ich eher ein Mix gewesen.
EDIT hat sich erledigt. Das Event wird nur einmal gesendet (auch beim iPhone selbst)


-Szene 1, Ebene 'AS', Bild 1, Zeile 18 1118: Implizite Umwandlung von einem Wert mit statischem Typ Object in einen möglicherweise nicht verwandten Typ flash.display:DisplayObject.

-Szene 1, Ebene 'AS', Bild 1, Zeile 22 1118: Implizite Umwandlung von einem Wert mit statischem Typ Object in einen möglicherweise nicht verwandten Typ flash.display:DisplayObject.

-->LG<--

Sollte jetzt im Script (rote Schrift) behoben sein.

MFG ad86
 
Zuletzt bearbeitet von einem Moderator:
D

DaFunsel

Guest

AW: Swipe Gesture

Da ist noch ein Fehler
Code:
if (gotoRight && ![COLOR=Red]gotoLeftt[/COLOR]){
So ganz werde ich da noch nicht schlau raus. Beim Testen kann ich den MC mit den vier 320x480 Bildern nur ein paar Pixel nach links/rechts schieben.
Das heißt ja auch, dass das Ende vom Anfang nicht definiert wurde,oder?
Ich will ja beim start das Anfangsbild und darf dann nur nach rechts swipen, weil wenn ich nach links swipe, ist der MC weg und komme nicht zurück. Das selbe am Ende.

Könntest du mir bei Gelegenheit die anderen Anweisungen auch mit Kommentaren versehen?

-->LG<--
 
A

ad86

Guest

AW: Swipe Gesture

Hi,

also nochmal zum klarstellen:

Du musst minX und maxX ändern. Wenn Du eine init-Methode hast, kannst Du beides setzen:

Code:
minX=-myObject_mc.width+myWidth; //myWidth ist die Breite des letzten Bildes
maxX= 0;

MFG ad86
 
D

DaFunsel

Guest

AW: Swipe Gesture

Mhh.
Nungut, dann werde ich da mal ein wenig mit basteln. Ich muss jetzt leider an die Arbeit. Evtl. melde ich mich heute Abend nochmal. Werde mir dann nochmal alles in Ruhe angucken, vill. verstehe ich ja etwas:)

schonmal vielen dank.

-->LG<--
 
D

DaFunsel

Guest

AW: Swipe Gesture

Hi.

Ich bekomme es nicht wirklich hin.
Den Endpunkt nach links habe ich jetzt. Nach rechts ist es immer ein wenig zu viel, ca. 15px.
Egal wieviel ich noch dazupacke/wegnehme, es geht nur zu viel nach rechts.
Code:
var minX:Number=-myObject_mc.width+520; //myWidth ist die Breite des letzten Bildes
var maxX:Number= 160;//maximale x-Position bei swipe rechts
//Beides ist aber nicht exakt, hängt von movVal ab.
var moveVal:Number=50;//Betrag pro Frame
Auch wenn ich den Endpunkt nach rechts finden würde, habe ich die Zwischenschritte nicht.
Ich habe ja in dem MC vier Bilder á 320x480 px. Wenn ich nach rechts swipe, möchte ich ja nicht gleich bis zum Ende, sondern das nächste Bild sehen. Vill. habe ich jetzt auch etwas in meiner Müdigkeit übersehen. Wenn es morgen nicht so spät wird, mache ich mich nochmal daran.
Mal sehen ob es dann etwas gibt.

-->LG<--
 
Zuletzt bearbeitet von einem Moderator:
A

ad86

Guest

AW: Swipe Gesture

Hi,

Code:
var minX:Number=-myObject_mc.width+520; //myWidth ist die Breite des letzten Bildes
var maxX:Number= 160;//maximale x-Position bei swipe rechts
//Beides ist aber nicht exakt, hängt von movVal ab.
var moveVal:Number=50;//Betrag pro Frame

MIch wundert es, warum +520. Normalerweise müsste es +320 und nicht +520 sein, da jedes BIld von Dir 320px breit ist. Vorausgesetzt Das erste BIld in Deinem MC ist auf Position (0,0):

Auch wenn ich den Endpunkt nach rechts finden würde, habe ich die Zwischenschritte nicht.
Ich habe ja in dem MC vier Bilder á 320x480 px. Wenn ich nach rechts swipe, möchte ich ja nicht gleich bis zum Ende, sondern das nächste Bild sehen. Vill. habe ich jetzt auch etwas in meiner Müdigkeit übersehen.

Mein Fehler. Klar das Du nicht vom ersten zum letzten BIld sofort möchtest. Ich hab das Script oben angepasst (rote Schrift). Ich hoffe da ist jetzt kein Bug drin. Sonst muss ich wohl Schädlingsbekämpfung betreiben. ;)

MFG ad86
 
Zuletzt bearbeitet von einem Moderator:
D

DaFunsel

Guest

AW: Swipe Gesture

Hi.
Also das funktioniert 100%tig. Ich habe den MC nocheinmal angepasst das er auch wirklich auf x=0 ist. Beim testen muss ich manchmal 2x am Anfang/Ende swipen damit er reagiert, könnte das am "removeEventListener" liegen?
Wofür genau steht denn eigentlich das "moveVal"? Für die BpS?
Ich werde damit die Tage noch ein wenig spielen, wenn sonst noch was unklar ist, melde ich mich.
Nochmals vielen Dank:)

P.S.: Das Gift für die Krabbeltiere kannst du dir sparen ;)

-->LG<--
 
A

ad86

Guest

AW: Swipe Gesture

Hi,

Also das funktioniert 100%tig. Ich habe den MC nocheinmal angepasst das er auch wirklich auf x=0 ist. Beim testen muss ich manchmal 2x am Anfang/Ende swipen damit er reagiert, könnte das am "removeEventListener" liegen?
Sollte eigentlich nicht daran liegen.
EDIT: Ich hab es selbst mal bei mir getestet. Natürlich ohne swipe, das gibt es ja nicht in CS4. Und da funktioniert alles.

Mal halbwegs erklärt:
Du führst einen Swipe nach links aus. In der Methode onSwipe wird es erkannt. Dort setzt er currentIndex um eins hoch, sofern er noch nicht das Ende (also Anzahl -1) der Bilder erreicht hat. Dann ruft er animateToLeft. Dort überprüft er, ob gotoLeft==true und gotoRight==false ist, was der Fall ist. Sollte die aktuelle x-Position des MC (also e.target) noch größer sein als der Minuswert mal der Gesamtbreite + der Breite des letzten Bildes, dann wird der MC weiter nach links bewegt. IN dem Fall, in dem die Bedingung nicht mehr stimmt, setzt er den MC auf den passenden x-Wert aus dem aktuellen Index (currentIndex) mal der Breite eines Bildes mal Minus, da wir ja nach links möchten. ZUdem wird gotoLeft auf false gesetzt. Da gotoRight ebenfalls false ist, ist die letzte Bedingung erfüllt, und er kann den EventListener löschen.

Möglichkeiten zur Behebung wären:
1. Gucken ob das Swipe-Event in der Methode onSwipe ankommt (durch ein trace-Befehl) und bei jedem Swipe gucken, ob in der Konsole der trace-Befehl ausgeführt wird. EDIT: Sollte hier dran liegen, da es bei mir ja funktioniert (mit BTN).
2. Sollte das der Fall sein, gucken, wo er nicht sofort reagiert. Ebenfalls mit trace-Anweisungen.

Wofür genau steht denn eigentlich das "moveVal"? Für die BpS?
Ich werde damit die Tage noch ein wenig spielen, wenn sonst noch was unklar ist, melde ich mich.

moveVal beschreibt den Wert, den der MC in jedem Frame sich weiter bewegt. Wenn Du die Framerate (in Flash unter Einstellungen, wenn nichts markiert ist) mal auf 10 oder so setzt, würdest Du sehen, wie der MC sich langsam nach rechts oder links bewegt.

MFg ad86
 
Zuletzt bearbeitet von einem Moderator:
D

DaFunsel

Guest

AW: Swipe Gesture

Hi.
War und bin die letzten/nächsten Tage sehr viel unterwegs.
Mit dem Rest muss ich mich mal in Ruhe beschäftigen.
Ich wollte nur nochmal was berichten:

Beim Testen ist mir was ganz doofes aufgefallen. Ich habe meine Bilder durch MC´s ersetzt. Dort sind BTN´s und Grafiken drin. Eigentlich läuft auch alles, ich war nur ein wenig erschrocken als ich swipen wollte und durch Zufall über die BTN´s gestrichen habe. Auf einmal hat sich der BTN verschoben:p.
Der Event wird irgendwie für "alles" (sprich: den MC + Inhalt) übernommen. Ich habe auch versucht alles in andere Symbole zu konvertieren oder sie als Rohdatei zu lassen.
Leider kann ich immer wieder die BTN´s, Grafiken etc. swipen :)

-->LG<--
 
A

ad86

Guest

AW: Swipe Gesture

Hi,

Beim Testen ist mir was ganz doofes aufgefallen. Ich habe meine Bilder durch MC´s ersetzt. Dort sind BTN´s und Grafiken drin. Eigentlich läuft auch alles, ich war nur ein wenig erschrocken als ich swipen wollte und durch Zufall über die BTN´s gestrichen habe. Auf einmal hat sich der BTN verschoben:p.

Wieso doof. Das ist ein Feature ;)

Der Event wird irgendwie für "alles" (sprich: den MC + Inhalt) übernommen. Ich habe auch versucht alles in andere Symbole zu konvertieren oder sie als Rohdatei zu lassen.
Leider kann ich immer wieder die BTN´s, Grafiken etc. swipen :)

Wie gesagt, ich kann es nicht testen, aber ich habe das Script oben geändert (rote Schrift) und es sollte nicht mehr passieren. Hoffe ich zu mindestens.
Auch wenn mich es wundert, wenn Du nur einmal
Code:
myObject_mc.addEventListener(TransformGestureEvent.GESTURE_SWIPE , onSwipe);
geschrieben hast, dürfte es eigentlich nicht passieren.

MFG ad86
 
D

DaFunsel

Guest

AW: Swipe Gesture

Der erste Vorschlag ganz am Anfang funktioniert.
Jetzt kann ich nur den MC swipen, die Fläche wo BTN´s und Grafiken sind, werden ja jetzt nicht mehr zum Swipen genommen, somit steht nur die freie Fläche in dem MC zur Verfügung. Ist es machbar, dass man sagt:
Die komplette Fläche des zu swipenden MC´s steht zur Verfügung, der Inhalt kann aber nicht einzeln geswiped werden. Also so wie jetzt, nur das man eine Art Maske über dem MC hat, die als ganze Angriffsfläche gilt.

-->LG<--
 
A

ad86

Guest

AW: Swipe Gesture

Hi,

sollte jetzt funktionieren. (Ist wieder die rote Schrift). Hoffe ich.

MFG ad86
 
Zuletzt bearbeitet von einem Moderator:
D

DaFunsel

Guest

AW: Swipe Gesture

Owei:eek:
Code:
[B]Szene 1, Ebene 'AS', Bild 1, Zeile 19    1118: Implizite Umwandlung von einem Wert mit statischem Typ Object in einen möglicherweise nicht verwandten Typ flash.display:MovieClip.
[/B]
Nochmal:
Code:
Szene 1, Ebene 'AS', Bild 1, Zeile 23    1118: Implizite Umwandlung von einem Wert mit statischem Typ flash.display:DisplayObject in einen möglicherweise nicht verwandten Typ flash.display:MovieClip.
Szene 1, Ebene 'AS', Bild 1, Zeile 27    1118: Implizite Umwandlung von einem Wert mit statischem Typ Object in einen möglicherweise nicht verwandten Typ flash.display:DisplayObject.
 
Zuletzt bearbeitet von einem Moderator:
A

ad86

Guest

AW: Swipe Gesture

Hi,

sorry, hätte schon früher geantwortet, aber übersehen, dass es schon eine zweite Seite gibt. :D

Code:
import flash.ui.Multitouch;
import flash.ui.MultitouchInputMode;
Multitouch.inputMode = MultitouchInputMode.GESTURE;

var moveVal:Number=50;//Betrag pro Frame
var imgCount:int=4;//Anzahl der Bilder
var imgSize:int=320;//Groesse eines Bildes
var currentIndex:int=0;//Welches Bild angezeigt wird
var gotoRight:Boolean=false;//OB swipe nach rechts oder nicht
var gotoLeft:Boolean=false;//OB swipe nach links oder nicht

myObject_mc.addEventListener(TransformGestureEvent.GESTURE_SWIPE , onSwipe);

//Funktion ueberprueft, ob das DisplayObject mit dem Namen mcName in parent_mc, oder seinen parent-Object enthalten ist.
function checkParent(mcName:String, parent_mc:DisplayObject):[COLOR="red"]DisplayObject[/COLOR]{
   //So lange das DisplayObject mit dem Namen mcName nicht gefunden wurde UND man noch nicht auf das stage-Objekt gestoßen ist, führe die Schleife aus.
   while (parent_mc.name!=mcName && parent_mc!=this.stage){
      parent_mc=parent_mc.parent;//Neues parent_mc-Objekt ist das parent-Objekt von parent_mc
   }
   if (parent_mc==this.stage){
      return null;//Sollte parent_mc das stage-Objekt sein, gib null zurueck
   }
   return parent_mc;//Sonst gib das Objekt mit dem Namen mcName zurueck
}

function onSwipe (e:TransformGestureEvent):void{
   var mc:[COLOR="Red"]DisplayObject[/COLOR]=checkParent("myObject_mc", [COLOR="Red"](e.target as DisplayObject)[/COLOR]);
   if (mc==null){//Das Display-Objekt wurde nicht gefunden, also raus aus dieser Methode
      return;
   }
   if (e.offsetX == 1) {
      if (currentIndex>0){//Wenn currentIndex groesser 0, kann man immer noch nach rechts
         currentIndex--;
         animateToRight(mc);
      }
   }
   if (e.offsetX == -1) {
      if (currentIndex<imgCount-1){//Wenn currentIndex kleiner als imgCount-1, kann man immer noch nach links
         currentIndex++;
         animateToLeft(mc);
      }
   }
}

//Wenn swipe nach rechts, setze die Boolean-werte und fuege den EventListener hinzu
function animateToRight(obj:DisplayObject):void{
   gotoRight=true;
   gotoLeft=false;
   obj.addEventListener(Event.ENTER_FRAME, moveObjHandler);
}

//Wenn swipe nach links, setze die Boolean-werte und fuege den EventListener hinzu
function animateToLeft(obj:DisplayObject):void{
   gotoLeft=true;
   gotoRight=false;
   obj.addEventListener(Event.ENTER_FRAME, moveObjHandler);
}

function moveObjHandler(e:Event):void{
   if (gotoLeft && !gotoRight){
      if (e.target.x> -currentIndex*imgSize+moveVal){ //Wenn x-Position noch größer als aktueller Index*imgSize + moveVal, dann kann x-Position nochmal nach links
         e.target.x-=moveVal;
      }
      else{
         e.target.x= -currentIndex*imgSize;
         gotoLeft=false;//Sonst darf die xPosition nicht weiter nach links gehen
      }
   }
   if (gotoRight && !gotoLeft){
      if (e.target.x< -currentIndex*imgSize-moveVal){//Wenn x-Position noch kleiner als aktueller Index*imgSize + moveVal, dann kann x-Position nochmal nach rechts
         e.target.x+=moveVal;//Sonst darf die xPosition nicht weiter nach rechts gehen
      }
      else{
         e.target.x=-currentIndex*imgSize;
         gotoRight=false;
      }
   }
   if (!gotoRight && !gotoLeft){//Wenn die XPosition weder nach links noch nach rechts, dann entferne EventListener
      e.target.removeEventListener(Event.ENTER_FRAME,moveObjHandler);
   }
}

MFg ad86
 
Zuletzt bearbeitet von einem Moderator:
D

DaFunsel

Guest

AW: Swipe Gesture

:lol: Das kenne ich.

Jetzt läuft alles. Abgefahren, hehe.
Es ist nur gerade viel Input. Habe schon knapp 14 Stunden Arbeit hinter mir.
Ich werde mich, wie schon geschrieben, irgendwann in den nächsten Tagen intensiver mit dem Projekt auseinandersetzen. Was total nett wäre, wenn du Zeit und Lust hast, wieder die Kommentare zu schreiben. Ich werde über die Tage erst einmal den Überblick verlieren und so kann ich auch versuchen das Script zu verstehen.
Ich danke dir schonmal vielmals. ;)

-->LG<--
 
A

ad86

Guest

AW: Swipe Gesture

Hi,

Was total nett wäre, wenn du Zeit und Lust hast, wieder die Kommentare zu schreiben. Ich werde über die Tage erst einmal den Überblick verlieren und so kann ich auch versuchen das Script zu verstehen.
Ich danke dir schonmal vielmals.

Sollte jetzt im Script (auf Seite 2) sein. Falls trotzdem noch eine Stelle unklar ist, einfach fragen.

MFg ad86
 
Bilder bitte hier hochladen und danach über das Bild-Icon (Direktlink vorher kopieren) platzieren.
Antworten auf deine Fragen:
Neues Thema erstellen

Willkommen auf PSD-Tutorials.de

In unseren Foren vernetzt du dich mit anderen Personen, um dich rund um die Themen Fotografie, Grafik, Gestaltung, Bildbearbeitung und 3D auszutauschen. Außerdem schalten wir für dich regelmäßig kostenlose Inhalte frei. Liebe Grüße senden dir die PSD-Gründer Stefan und Matthias Petri aus Waren an der Müritz. Hier erfährst du mehr über uns.

Stefan und Matthias Petri von PSD-Tutorials.de

Nächster neuer Gratisinhalt

03
Stunden
:
:
25
Minuten
:
:
19
Sekunden

Flatrate für Tutorials, Assets, Vorlagen

Statistik des Forums

Themen
175.158
Beiträge
2.581.880
Mitglieder
67.226
Neuestes Mitglied
Alec168
Oben