Anzeige
Tutorialbeschreibung

Flash Bilder Gallerie mit thumbs

Flash Bilder Gallerie mit thumbs

Hier zeige ich Euch wie man eine kleine Flashgallerie mit Thumbnails erstellt.
Verwendet wird unter Anderem MovieClip.prototype, das Einlesen externer Daten aus einem Textdokument und eine Scrollfunktion.
Ich denke dieses Tut wendet sich an Leute die schon ein wenig Erfahrung mit Flash haben.  Wie man die Werkzeuge benutzt, Instanzen bennent und ins Codefenster gelangt setze ich hier einfach einmal voraus. Die angehängten Files sind in Flsh 8 gespeichert, der Code sollte aber ab MX2004 funktionieren.
Dies ist mein erstes Tutorial auf dieser Seite, ich hoffe es ist nicht allzu Aramäisch und Ihr kommt damit zurecht.

Viel Spaß also nun


Vorbereitung:

Um dieses Tutorial mitmachen zu können müsst Ihr ein paar kleine Vorbereitungen treffen:

Erstellt also in dem Verzeichniss in dem Ihr nachher Euren Flashfile abspeichern wollt zwei weitere Ordner. Den einen nennt ihr 'gross', den anderen nennt ihr 'klein'. In diese Ordner packt Ihr Eure Bilder, in den 'klein'en die Thumbs mit einer Größe von 150*113px und in den 'gross'en die Grossen Bilder mit einer Grösse von 600*450px. Ich habe in meinem Beispiel *.jpgs verwendet. Wichtig ist nur, das die grossen Bilder genau gleich heissen wie die jeweils dazu gehörenden kleinen Bilder und das es keine progressiv jpgs, aber auf jeden Fall jpgs sind.

Aussserdem erstellt Ihr Bitte einen Textfile den Ihr 'bilder.txt' nennt. In diesen Textfile tragt Ihr die Namen Eurer Bilder ein, allerdings ohne die Endung (.jpg). damit Flash auch erkennt welche Daten es aus dem Textfile auslesen muss beginnt Ihr Bitte den String mit '&pix=' und beendet ihn mit einem '&'. Die einzelnen Namen trennt Ihr bitte durch drei Senkrechte Striche '|||' (die erhält man wenn man auf AltGr&<> drückt ^^). Wir werden nacher in Flash diesen String anhand dieser Trennzeichen zerlegen. Euer Textfile sollte dann in Etwa so aussehn:

&pix=bild1|||bild2|||bild3|||Bild4|||Bild5&


Natürlich könnt Ihr diese Liste um beliebig viele Bilder erweitern.

Schritt 1:
Kommen wir also ins Flash:

In Flash erstellen wir zunächst einmal unser Haupt - Anzeigefenster. In dieses werden nachher die großen Bilder eingeladen. Zieht also einen Rahmen auf der Bühne auf mit einer Grösse von 600*450px und positioniert Ihn bei 100*5px. Markiert dann den Rahmen, drückt F8 und macht ihn damit zu einem Symbol(zu einem Movieclip) und benennt diesen MC als 'Rahmen'. Gebt dem Rahmen auf der Bühne den Instanznamen 'rahmen'.

In unserem Flashfilm benötigen wir an drei Stellen einen leeren Container. In diesen werden später unsere Biler eingeladen. Wir drücken also Strg&F8, wählen 'MovieClip', nennen diesen leeren MC 'Container' und bestätigen mit Enter.
Jetzt klicken wir doppelt auf den MC 'rahmen' in unserer Bibliothek (F11) um in diesen MC zu gelangen. Zunächst vergewissern wir uns, das der Rahmen mit seiner linken oberen Ecke auf 0*0px liegt. Dann erstellen wir eine neue Ebene, ziehen sie unter die bereits vorhandene und nennen sie 'container'. In diese Ebene ziehen wir unseren MC 'Container' und benennen diese Instanz als 'cont'.
Der MC 'rahmen' sollt nun also wie folgt aussehn:

Positionierung des ersten ContainersBilder


Wieder in der Hauptzeitleiste erstellen wir einer neue Ebene (nennen wir sie cont). In diese Ebene ziehen wir ebenfalls den MC 'Container' und geben ihm den Instanznamen 'cont'. Ich habe meinen cont bei 100*475px positioniert.

Jetzt brauchen wir noch einen Movieclip, unseren späteren Button. Also, ziehen wir auf der Hauptbühne ein Rechteck (nur die Linien, ohne Füllung) mit einer Größe von 150*113px auf, markieren es, drücken F8 (in Symbol Convertieren), wählen Movieclip und nennen ihn 'button'. Wichtig hierbei ist, das Ihr unter 'Erweitert' noch den Punkt 'Export für ActionScript' aktiviert.  Als Bezeichner hat sich automatisch 'button' eingetragen. Drückt also jetzt Enter und löscht den Movieclip Button wieder von der Haupt- Bühne, wir werden ihn nachher über Script einladen. In der Bibliothek klicken wir wieder doppelt auf den MC 'Button'. Im MC 'Button' erstellen wir wieder eine neue Ebene, nennen Sie 'cont' und ziehen sie wieder unter die Ebene in der unser Rahmen liegt. Ihr ahnt es schon, auch hier ziehen wir wieder den leeren Container rein, positionieren ihn wieder bei 0*0px und instanzieren ihn als 'cont'. Bei mir sieht das ganze jetzt also so aus:

Positionieren des Containers im ButtonBilder


Schritt 2:

So,  nun zum Script.
Ich schreibe allen Script in eine eigene Ebene, diese nenne ich 'Actions'. Das ist deutlich übersichtlichre als wenn man den Code schön säuberlich in allen Möglichen Frames versteckt. (Alles schon gesehen^^)
Laden wir uns also via Script die Liste die wir in unseren Textfile erstellt haben in Flash ein. Hierzu erstellen wir ein neues LoadVars Object. In diese laden wir unseren Textfile. Sobald die Daten geladen wurden lassen wir den erhaltenen String (objekt 'bilder', index 'pix') anhand der ||| zerlegen. Der Code sieht  wie folgt aus:


bilder = new LoadVars();
bilder.load('bilder.txt');
bilder.onLoad = function(ok) {
    if (ok) {
        //splitten der eingeladenen Daten anhand der senkrechten Striche
        allpix = bilder['pix'].split('|||');
        trace(allpix);
   } else {
        trace('konnte Bilderliste nicht laden');
    }
};



Wenn Ihr den Film jetzt testet solltet Ihr also in etwa so eine Ausgabe erhalten:

bild1,bild2,bild3


Schritt 3:

So, kümmern wir uns also um den Aufbau unserer Buttons
Wir schreiben uns jetzt also eine Methode, die die Buttons in den Container einlädt und rufen diese Methode in der eben geschriebenen onLoad- Anweisung auf.
ersetzen wir also die Zeile 'trace(allpix);' durch 'buttonaufbau(allpix);'
So rufen wir die Methode buttonaufbau, die wir gleich schreiben werden auf und übergeben ihr unser array 'allpix'. In unserer Methode 'buttonaufbau' lassen wir einfach in einer for- schleife den Button so oft in unseren container einladen wie es Elemente im übergebenen Array pix gibt.
der Code hierfür sieht wie folgt aus:


function buttonaufbau(pix) {
    for (i=0; i<pix.length; i++) {
        cont.attachMovie('button', 'button'+i, i, this);
        this.clip = eval('cont.button'+i);
        this.clip._x = (10+this.clip._width)*i;
        this.clip.galleriebutton(pix[i]);
    }
}


Wie eine for-Schleife funktioniert werde ich hier nicht gross und breit erklären, google sollte da dem Unwissendem helfen ;-).
Die Zeile this.clip = eval('cont.button'+i); ist nicht wirklich sauber, da man auf die Verwendung von eval verzichten sollte, ich habe sie hier nur verwendet um den Umfang an Erklärungen nicht allzu sehr zu sprengen. Mit diesem eval 'evaluieren' wir schlicht und einfach unseren eben erstellten Button 'button'+i und können ihn dadurch einfach über this.clip ansprechen.
In der Zeile   this.clip._x = (10+this.clip._width)*i; positionieren wir den Button auf der x- Achse und geben ihm einen Versatz um seine eigene (Breite+10)*i.
Da i im ersten Durchgang der Schleiffe ja 0 ist und (breite+10)*0 ja immer 0 ist, wird der Button nicht nach rechts versetzt. Dies kommt erst im zweiten durchlauf zum tragen.
Die 10 in dieser Zeile versetzt den Button einfach noch einmal um 10 nach rechts, damit er nicht bündig an seinem linken Vorgänger anschliesst.

Interessant ist die folgende Zeile ' this.clip.galleriebutton(pix[i]);'.
Hier vererben wir unserem Button dem prototype galleriebutton und übergeben an den prototype den namen des Bildes anhand seines index im array pix '(pix[i])'.
Was ein Prototype ist und wie wir ihn schreiben werde ich im nächsten Schritt erklären.
Zunächst sollte man aber jetzt die Kollegen beeindrucken indem man cool zur Kaffeemaschine schlendert, ganz wichtig guggt und vor sich hinbrabbelt man müsse jetzt einen ersten Prototype zusammenpfriemeln, was eine unglaublich wichtige, komplizierte und gefährliche Angelegenheit sei, man bräuchte jetzt mindestens einen Liter Kaffee und dürfe die nächsten zwei bis drei Stunden auf gar keinen Fall gestört werden. Nicht mal, -besser 'schon gar nicht' - vom Chef 
Bilder
. Ich geh derweil eine rauchen, lass mir meinen Kaffee bringen und wir sehen und in Schritt 4 wieder.

-Kaffepause-

Schritt 4:

Gut gestärkt und als absolut durchgedreht abgestempelt geht es jetzt also weiter mit unserem prototype.
In Flash gibt es verschiedene Anwendungen des prototype- objektes. Allgemein rührt der prototype aus dem Umgang mit Klassen her. Die erstellt Klasse wird also an den Prototype angehängt, vererbt ihm seine Eigenschaften und übernimmt die des Prototypes. In der OOP in Flash eine mächtige und fast unausweichliche Sache.
Da beim Aufruf des Prototypes dieser im Ablauf schon vorgekommen sein muss schreiben wir ihn also an den Anfang(!!) unseres Codes. Ansonsten gibt Flash zwar keine Fehlermeldung aus, kann aber unser Objekt (der Button) auch nicht anhängen.
Schreiben wir also den Prototype wie folgt:


MovieClip.prototype.galleriebutton = function(namen) {
    // einladen des Entsprechenden Bildes in den Buttoncontainer
    this.cont.loadMovie('klein/'+namen+'.jpg', 1);
    // was soll passieren wenn man auf den Button klickt?
    this.onRelease = function() {
        //einladden des grossen Bildes in das Anzeigefenster
        rahmen.cont.loadMovie('gross/'+namen+'.jpg');
    };
};


Eigentlich keine Zauberei. Wir benötigen nur eben diesen Prototype, da wir die onRelease Prozedur nicht in unsrer Vorschleife erstellen können. Diese läuft ja weiter und nach dem Fertigen Durchlauf würde nur noch das letzte Element im Array pix geladen. Alle Aktionen und Effekt die der Button haben soll könnt Ihr in diesem Prototype verankern.
So, eigentlich ist die Basis für unsere Galerie schon fertig. Wenn wir den Film jetzt testen sehen wir, das die Thumbs in die Buttons geladen werden und das auf klick auch die großen Bilder in das Anzeigefenster geladen werden. Allerdings eben erst nach dem ersten klick.
Klar, denn wir haben Flash ja nur in der onRelease Prozedur gesagt er solle etwas ins Anzeigefenster rein laden. Erweitern wir also unsere function buttonaufbau() um eine weitere Zeile (ganz ans Ende, nach 'this.clip.galleriebutton(pix[i]);'):


rahmen.cont.loadMovie('gross/'+pix[0]+'.jpg');


Damit laden wir das Bild mit dem Namen des ersten Index in unserem Array 'pix' in das Anzeigefenster
Unser gesamter Code sollte also bisher so aussehn:


MovieClip.prototype.galleriebutton = function(namen) {
    // einladen des Entsprechenden Bildes in den Buttoncontainer
    this.cont.loadMovie('klein/'+namen+'.jpg', 1);
    // was soll passieren wenn man auf den Button klickt?
    this.onRelease = function() {
        //einladden des grossen Bildes in das Anzeigefenster
        rahmen.cont.loadMovie('gross/'+namen+'.jpg');
    };
};
//Einladen des Textfiles
bilder = new LoadVars();
bilder.load('bilder.txt');
bilder.onLoad = function(ok) {
    if (ok) {
        //splitten der eingeladenen Daten anhand der senkrechten Striche und einladen in das Array allpix
        allpix = bilder['pix'].split('|||');
        // Aufruf der Methode buttonaufbau
        buttonaufbau(allpix);
    } else {
        trace('konnte Bilderliste nicht laden');
    }
};
// auslesen der Bilder aus dem Array das aus unserm Textfile geworden ist
function buttonaufbau(pix) {
    for (i=0; i<pix.length; i++) {
        cont.attachMovie('button', 'button'+i, i, this);
        this.clip = eval('cont.button'+i);
        this.clip._x = (10+this.clip._width)*i;
        this.clip.galleriebutton(pix[i]);
        rahmen.cont.loadMovie('gross/'+pix[0]+'.jpg');
    }
}


30 Zeilen für die Basis einer Gallerie ist doch schon mal gar nicht so schlecht.

 

Schritt 5 / die Schönheits- OP:

Was beim Testen jetzt auffällt ist, das bei einer entsprechenden Anzahl an Bildern, die Buttons über unseren rechten Bildrand herausragen.
Um das ein bisschen schöner zu gestalten bauen wir uns eine kleine Scrollfunktion, die die Buttons vertikal scrollbar macht.
Außerdem maskieren wir die Ebene mit den Buttons um ein schöneres Gesamtbild zu erhalten.

Schritt für Schritt gehen wir wie folgt vor:

Ich habe den Container in den wir unsere Buttons einladen direkt unter der linken Kante des Anzeigefensters positioniert. Ich möchte, das die Buttons auch nur direkt unter dem Anzeigefenster zu sehen sind, deswegen erstelle ich im folgenden Schritt eine Maske, die genau so breit ist wie unser Anzeigefenster. Wie breit Ihr Eure Maske macht bleibt natürlich voll und ganz Euch überlassen. Zunächst würde ich aber empfehlen meine Maße zu übernehmen, die entspr. Werte werden nämlich im folgenden Script benötigt.
Gehen wir also wie folgt vor:

Zunächst erstellen wir auf der Hauptzeitleiste eine neue Ebene, nennen sie 'Mask' und ziehen sie direkt über die Ebene 'cont'. In dieser Ebene 'Mask' ziehen wir ein Rechteck auf, welches 600px breit, 114px hoch ist und mit seiner linken, oberen Ecke direkt über dem Container (also bei 100*475px ) liegt.
Das sollte in etwa so aussehn:

Positionierung der MaskeBilder


Jetzt machen wir diese Ebene mit einem Rechtsklick-> Maske zur Maske, welche die Ebene 'cont' maskiert.
Beim Testen des Films stellen wir fest, das unsere Buttons zwar nicht mehr alle zu sehn sind, aber auch nicht mehr über den rechten Rand hinausragen.
Jetzt müssen wir also noch unseren Container mit den Buttons scrollbar machen.

Schritt 6:

Erstellen wir also zunächst ein Dreieck, welches nacher einer unserer Scrollbuttons ist.
Dazu erstellen wir eine neue Ebene in der HZL (Hauptzeitleiste). Nennen wir sie  'scrollbttns'. Hier ziehen wir ein Viereck auf, drehen das um  45 Grad,  schneiden die rechte  Hälfte ab und skallieren es in der Breite so, das es deutlich schmaler als hoch ist.

erstellung der ScrollbuttonsBilder


Jetzt markieren wir dieses Dreieck, drücken F8 und machen es zu einer Schaltfläche. Die dürft Ihr nennen wie Ihr wollt, ich nenne sie 'Scrollbttn'.
Der auf der HZL verbliebenen Instanz geben wir den Instanznamen 'links'. Diese Instanz kopieren wir (Strg&c), fügen sie an der selben Stelle wieder ein (Strg&Shift&v), drehen die Kopie um 180° (2* Strg&Shift&9) und verschieben sie nach rechts, so das sie neben unserer Maske liegt (ca bei 704px). Dieser Instanz geben wir den Namen 'rechts'.

Positionierung der ScrollbuttonsBilder


War auch nicht so wirklich schwer, oder? Ich denke es ist aber mal wieder an der Zeit die Kollegen zu beeindrucken.
Also, Strg&S drücken, wieder raus aus dem Büro, wichtig guggen, vom gelingen des Prototypen und seinen unendlichen Fähigkeiten schwärmen, der Sekretärin (wahlweise dem Sekretär) zublintzeln, Kaffee krallen und zurück ins Büro.

-Kaffeepause-

Schritt 7:


Kommen wir nun zum Code für unsere Scrollfunktion:
Zunächst Schreiben wir die RollOver und RollOut- Prozeduren:
Hängen wir also an das Ende unseres Codes folgende zeilen an:

versatz = 5;
rechts.onRollOver = function() {
    scrollen(-versatz);
};
rechts.onRollOut = function() {
    scrollen(0);
};
links.onRollOver = function() {
    scrollen(+versatz);
};
links.onRollOut = function() {
    scrollen(0);
};

Versatz gibt die Anzahl der Pixel an, um die, je onEnterFrame unser container nach links, oder rechts bewegt werden soll.
In jeder dieser Prozeduren wird die Methode 'scrollen' aufgerufen, nur wird in jeder Prozedur ein anderer Parameter übergeben. Anhand dieses Parameters entscheiden wir in der Methode 'scrollen' was wir mit unserem Container machen wollen.
Ist unser Parameter positiv, soll sich der Container nach rechts verschieben, ist er negativ, soll er sich nach links verschieben, ist er 0 soll die Scrollfunction gestoppt werden.
Kommen wir also zu unserer Methode Scrollen (Hier könnte man auch einen Prototype verwenden, um es aber ein bisschen bunter zu gestalten mache ich das hier auch über eine Methode):
In dieser wird nicht nur bestimmt in welche Richtung sich der Container bewegen soll, es wird auch noch geprüft ob tatsächlich noch weiter gescrollt werden muss, oder ob in diese Richtung alle Elemente dargestellt werden.
Schreiben wir also an das Ende unseres bisherigen Codes:

 function scrollen(richtung) {
    this.onEnterFrame = function() {
        if (richtung>0 && cont._x<100) {
            cont._x = cont._x+richtung;
        } else if (richtung<0 && cont._x>100-cont._width+590) {
            cont._x = cont._x+richtung;
        } else if (richtung == 0) {
            delete this.onEnterFrame;
        }
    };
}

Wie Ihr seht haben wir den übergebenen Parameter als 'Richtung' empfangen. Wir entscheiden jetzt in mehreren if() und else ifs() folgendes:
-ist der Parameter > als 0, soll sich ja der Container ja nach rechts bewegen. Dies soll er aber nur tun, solange die Position des Containers niedriger ist, als die Linke Ecke der Maske (weil wir ja sonst aus dem Anzeigebereich des 'thumbmenues' rausscrollen) Also:   if (richtung>0 && cont._x<100) { ...

-ist der Parameter < als 0, soll sich der Container ja nach links bewegen. Dies soll er aber nur solange tun, solange der letzte Thumbnailbutton gerade so in unseren Anzeigeberiech des 'thumbmenues' hinein reicht. Also: else if (richtung<0 && cont._x>100-cont._width+590) {... (590 ist die Breite meiner Makse -10)

und zu guter Letzt, ist der Parameter = 0, soll das scrollen aufhören, also else if (richtung == 0) { delete this.onEnterFrame;...

 


So, im Grossen und ganzen ist unsere Gallerie jetzt fertig. Zur Kontrolle noch einmal der komplette Code:

MovieClip.prototype.galleriebutton = function(namen) {
    // einladen des Entsprechenden Bildes in den Buttoncontainer
    this.cont.loadMovie('klein/'+namen+'.jpg', 1);
    // was soll passieren wenn man auf den Button klickt?
    this.onRelease = function() {
        //einladden des grossen Bildes in das Anzeigefenster
        rahmen.cont.loadMovie('gross/'+namen+'.jpg');
    };
};
//Einladen des Textfiles
bilder = new LoadVars();
bilder.load('bilder.txt');
bilder.onLoad = function(ok) {
    if (ok) {
        //splitten der eingeladenen Daten anhand der senkrechten Striche und einladen in das Array allpix
        allpix = bilder['pix'].split('|||');
        // Aufruf der Methode buttonaufbau
        buttonaufbau(allpix);
    } else {
        trace('konnte Bilderliste nicht laden');
    }
};
// auslesen der Bilder aus dem Array das aus unserm Textfile geworden ist
function buttonaufbau(pix) {
    for (i=0; i<pix.length; i++) {
        cont.attachMovie('button', 'button'+i, i, this);
        this.clip = eval('cont.button'+i);
        this.clip._x = (10+this.clip._width)*i;
        this.clip.galleriebutton(pix[i]);
        rahmen.cont.loadMovie('gross/'+pix[0]+'.jpg');
    }
}
versatz = 5;
rechts.onRollOver = function() {
    scrollen(-versatz);
};
rechts.onRollOut = function() {
    scrollen(0);
};
links.onRollOver = function() {
    scrollen(+versatz);
};
links.onRollOut = function() {
    scrollen(0);
};
function scrollen(richtung) {
    this.onEnterFrame = function() {
        if (richtung>0 && cont._x<100) {
            cont._x = cont._x+richtung;
        } else if (richtung<0 && cont._x>100-cont._width+590) {
            cont._x = cont._x+richtung;
        } else if (richtung == 0) {
            delete this.onEnterFrame;
        }
    };
}


_________________________________________________________________________________________________________
Hier noch einmal ein Screen vom fertigen Flashfile:

Fertiger FlashfileBilder



Das wars auch schon,
Ich hoffe Ihr hattet ein klein wenig Spass und habt ein bisschen was gelernt. Ich habe Euch die kompletten Dateien noch einmal unter www.sd-fx.de/psdtuts/statikfiles/download.php?id=15488a36 abgelegt. Viel Erfolg beim nachbasteln und viel Spass mit der Gallerie.
Sollte es weitere Fragen geben bin ich natürlich jeder Zeit bereit zu helfen. Aber bitte addet mich nicht gleich alle im ICQ oder bombardiert mich mit PMs, schliesslich sollen ja alle was davon haben
Bilder
. Ich bin gerne bereit Euch hier oder im Forum zu helfen.

So gehabt Euch denn wohl,

LG B2B

Kommentare
Achtung: Du kannst den Inhalt erst nach dem Login kommentieren.
Portrait von Kreintuleb
  • 16.10.2012 - 11:04

Gutes Turtourial ...

Portrait von Susan99
  • 22.05.2012 - 21:34

Ein schönes Tutorial, sehr gut erklärt. Vielen Dank!

Portrait von znaxi
  • 02.03.2012 - 11:17

Vielen Dank! Funktioniert super

Portrait von karol1988
  • 07.09.2011 - 12:10

Vielen Dank Hat alles Super geklappt :)

Portrait von karol1988
  • 07.09.2011 - 12:09

Vielen Dank Hat alles Super geklappt :)

Portrait von poisonchild
  • 23.05.2011 - 19:01

Danke, werde es vll. in meine Website einbauen. Danke

Portrait von akpotosufredrick
Portrait von annala
  • 01.10.2010 - 02:14

prima tut ....musste mich ziemlich anstrengen um es für meine bedürfnisse zurecht zu biegen, da ich doch eher noch ein anfänger bin, aber so lern man ja ;-). nun scheitere ich aber leider daran die galerie in meine flash website einzubauen, könnte das evtl. an meiner navigation in den frames liegen? die galerie liegt bei mir auf frame 2 und wird mit:
on (release) {
gotoAndStop(2);
}

aufgerufen. hab schon diverses ausprobiert, aber da ich immer wieder an dem problem scheitere projekte in die site zu intergrieren, welche für sich prima laufen, dachte ich mir ich frag mal ;-)

Portrait von CraYon
  • 03.05.2010 - 12:19

Gutes tutorial hat sehr gut geklappt

Portrait von suti5
  • 25.04.2010 - 11:03

Super genau das habe ich gesucht.

Portrait von terminator60000
  • 12.04.2010 - 14:35

wow hammer Tutorial, auch mit ein wenig witz erklärrt! finde ich super^^

Portrait von terminator60000
  • 12.04.2010 - 12:41

xD um diese Uhrzeit machst du ein Tutorial? hehe
naja, wer nicht schlafen muss hehe^^

also ich finde das Turorial auf den Ersten Blick schön, ich werde es mal versuchen nachzubauen ;-)

Portrait von Ella90
  • 08.04.2010 - 14:17

Ganz interessant aber leider nicht das was ich suche : (

Portrait von renateheine
  • 02.02.2010 - 15:11

Ich weiß nicht wie oft ich schon von vorne anfing: aber z.B. schreibst Du:

In unserem Flashfilm benötigen wir an drei Stellen einen leeren Container. In diesen werden später unsere Biler eingeladen. Wir drücken also Strg&F8, wählen 'MovieClip', nennen diesen leeren MC 'Container' und bestätigen mit Enter.
Jetzt klicken wir doppelt auf den MC 'rahmen' in unserer Bibliothek (F11) um in diesen MC zu gelangen. Zunächst vergewissern wir uns, das der Rahmen mit seiner linken oberen Ecke auf 0*0px liegt. Dann erstellen wir eine neue Ebene, ziehen sie unter die bereits vorhandene und nennen sie 'container'. In diese Ebene ziehen wir unseren MC 'Container' und benennen diese Instanz als 'cont'.
Der MC 'rahmen' sollt nun also wie folgt aussehn:

Bei mir sieht die Ebene aber nicht so aus; vermisse den Schritt wo bei dem MC Rahmen, die Ebene 1 plötzlich rahmen heißt.

Portrait von renateheine
  • 02.02.2010 - 14:54

bin ein Fastneuling und bei mir klappt es noch nicht. Habe auch Probleme mit der Beschreibung vom pdf; manchmal sind die Namen klein geschrieben, mal wieder groß; recht verwirrend; jedenfalls für mich

Alternative Portrait
-versteckt-(Autor hat Seite verlassen)
  • 21.10.2009 - 00:27

Kann mich den vergangenen Kommentaren nur anschließen.
Vielen Dank!

Portrait von o1e
o1e
  • 14.09.2009 - 20:28

bin absoluter flashneuling, und habe leider so meine probs das ganze umzusetzen und in den rest meiner flashseite einzufügen... trotzdem.. ich versuch es weiter

Portrait von renateheine
  • 02.02.2010 - 15:18

Hallo,
ist ja schon einige Zeit her, als Du Erfahrung (mit der Flash Bilder Galerie mit thumbs ) gemacht hast. Hat es bei Dir letztendlich dann geklappt? Habe nämlich auch so meine Probleme mit dem nachvollziehen der Beschreibung

Portrait von williamo
  • 11.07.2009 - 14:24

Tolles Tut.
Hier versteht sogar der Anfänger, wie es geht
Thx

Portrait von Nemesis_Steelfeather
x
×
×